home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Suzy B Software 2
/
Suzy B Software CD-ROM 2 (1994).iso
/
extras
/
programm
/
gemfsc20
/
gemfsc20.lzh
/
GEMFBIND
/
VSETATTR.S
< prev
next >
Wrap
Text File
|
1993-03-16
|
4KB
|
138 lines
;*========================================================================
;* VDIFAST Public Domain VDI bindings.
;*========================================================================
;*************************************************************************
;*
;* Attribute functions 1.
;* This random collection is all in one module because if you use any
;* one of these functions the overhead of having them all linked in is
;* only about 50 bytes.
;*
;* vatt_1i1r - Internal routine.
;* _vswr_mode - Set writing mode.
;* _vsl_type - Set polyline type.
;* _vsl_udsty - Set polyline user-defined style.
;* _vsl_color - Set polyline color.
;* _vsm_type - Set polymarker type.
;* _vsm_color - Set polymarker color.
;* _vst_rotation - Set text baseline angle.
;* _vst_font - Set text font/face.
;* _vst_color - Set text color.
;* _vst_effects - Set text special effects.
;* _vsf_interior - Set fill interior type.
;* _vsf_style - Set fill interior style.
;* _vsf_color - Set fill interior color.
;* _vsf_perimeter - Set fill perimeter visibility.
;*
;*************************************************************************
;*------------------------------------------------------------------------
;*-----------------------------------------------------------------------
;* vatt_1i1r
;* For VDI attribute calls that use 1 intin, 1 intout (most of them).
;* Entry: d0.w = VDI function number.
;*-----------------------------------------------------------------------
;*------------------------------------------------------------------------
vatt_1i1r:
; .cargs #8,handle.w,integer.w
handle = 8
integer = 10
link a6,#-2
; VContrl d0,,,#1
move.w handle(a6),-(sp) ; contrl[6]
clr.l -(sp) ; contrl[5,4]
move.w #1,-(sp) ; contrl[3]
subq.l #2,sp ; contrl[2]
clr.w -(sp) ; contrl[1]
move.w d0,-(sp) ; contrl[0]
subq.l #4,sp ;* -> ptsout
pea -2(a6) ;* -> intout
subq.l #4,sp ;* -> ptsin
pea integer(a6) ;* -> intin
pea 16(sp) ;* -> contrl
jmp vdicall
;*------------------------------------------------------------------------
;* Attribute stuff that uses 1 intin, 1 intout...
;*------------------------------------------------------------------------
globl _vswr_mode
_vswr_mode:
;* Set writing mode.
moveq.l #32,d0
bra vatt_1i1r
globl _vsl_type
_vsl_type:
;* Set polyline type.
moveq.l #15,d0
bra vatt_1i1r
globl _vsl_udsty
_vsl_udsty:
;* Set polyline user-defined style.
moveq.l #113,d0
bra vatt_1i1r
globl _vsl_color
_vsl_color:
;* Set polyline color.
moveq.l #17,d0
bra vatt_1i1r
globl _vsm_type
_vsm_type:
;* Set polymarker type.
moveq.l #18,d0
bra vatt_1i1r
globl _vsm_color
_vsm_color:
;* Set polymarker color.
moveq.l #20,d0
bra vatt_1i1r
globl _vst_rotation
_vst_rotation:
;* Set text baseline angle.
moveq.l #13,d0
bra.b vatt_1i1r
globl _vst_font
_vst_font:
;* Set text font/face.
moveq.l #21,d0
bra vatt_1i1r
globl _vst_color
_vst_color:
;* Set text color.
moveq.l #22,d0
bra.b vatt_1i1r
globl _vst_effects
_vst_effects:
;* Set text special effects.
moveq.l #106,d0
bra.b vatt_1i1r
globl _vsf_interior
_vsf_interior:
;* Set fill interior type.
moveq.l #23,d0
bra.b vatt_1i1r
globl _vsf_style
_vsf_style:
;* Set fill interior style.
moveq.l #24,d0
bra.b vatt_1i1r
globl _vsf_color
_vsf_color:
;* Set fill interior color.
moveq.l #25,d0
bra.b vatt_1i1r
globl _vsf_perimeter
_vsf_perimeter:
;* Set fill perimeter visibility.
moveq.l #104,d0
bra.b vatt_1i1r